2025年4月23日水曜日

I2C OLEDを試してみた

「M5STACK LCD Unitのファームウェアアップデート」の記事の際に記載した I2C OLEDディスプレイを動かしてみました。

本製品はタイトルや製品説明では、ドライバICはSSD1315 を使用しているとありましたが、詳細説明ではSSD1306を使用と記載されています。購入してから気が付きました...



詳しくは調べていませんが、SSD1315 はSSD1306  の上位互換らしいので、SSD1306として使用してみました。なお、OLEDのライブラリはAdafruit_SSD1306を使用して記述しました

#include <Wire.h>
#include <Adafruit_GFX.h>      // Ver 1.12.1
#include <Adafruit_SSD1306.h>  // Ver 2.5.13

#define SCREEN_WIDTH 128 // OLED 横設定
#define SCREEN_HEIGHT 64 // OLED 高さ設定
#define OLED_RESET    -1 // OLEDリセット(未使用:-1)
#define SCREEN_ADDRESS 0x3C // ボード上の設定:0x78に接続:0x3C、0x7Aに接続:0x3D

// ディスプレイの宣言
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);


void setup() {

  display.begin(SSD1306_SWITCHCAPVCC, SCREEN_ADDRESS);

}

void loop() {

  display.clearDisplay();      // 表示クリア
  display.setTextSize(2);      // テキストサイズ
  display.setTextColor(WHITE); // テキストカラー
  display.setCursor(0, 10);    // テキストの表示位置

  display.println("Hello World");
  display.display();           // テキスト表示

  delay(1000);

}

サクッと動いてしまいました。3ボードセットなので各ボードで動作チェックを行い、不良が無いことを先に確認しました

折角なのでスタックチャンアバターを表示しようと調べてみると、M5 GLASS2 unitで使用されているSSD1309はSSD1306と互換性があるという情報を見つけました。早速、ライブラリを変更して試してみます。予定通りスタックチャンを表示しますが、折角なので10秒ごとに表情が変わるようにしました

#include &ltM5UnitGLASS2.h>
#include &ltM5Unified.h>
#include &ltAvatar.h>

using namespace m5avatar;
m5avatar::Avatar avatar;

const Expression expressions[] = {
  Expression::Angry,
  Expression::Sleepy,
  Expression::Happy,
  Expression::Sad,
  Expression::Doubt,
  Expression::Neutral
};

const int expressionsSize = sizeof(expressions) / sizeof(Expression);
int idx = 0;

void setup() {
  auto cfg=M5.config();
  cfg.unit_glass2.pin_sda = 21; // SDA ピン設定
  cfg.unit_glass2.pin_scl = 22; // SCL ピン設定
  M5.begin(cfg);

  // OLED ディスプレイサイズ:128 x 64
  avatar.setScale(.4);         // 縮尺:.4 = 128/320
  avatar.setPosition(-88,-96); // ポジション:88 = (240-64)/2, 96 = (340-128)/2
  avatar.init();               // アバターの初期化
}

void loop() {
  M5.update();

  idx = rand() % expressionsSize;
  avatar.setExpression( expressions[idx] );
  
  delay(10000);

}

スタックチャンアバターは、320x240ディスプレイ用に準備されていますので、小さい液晶で表示する際は縮尺(avatar.setScale())やポジション(avatar.setPosition())の設定を変更する必要があります



とりあえず、動作したので良しとしました。結局、このOLED のディスプレイドライバは不明ですが、SSD1306、SSD1309、SSD1315は互換性があるようですね

参考にさせて頂きましたサイト:

2025年4月10日木曜日

ケチって互換DFplayer mini を買ったばかりに...

本来であれば、DFRobot のDFplayer mini を購入すればよいのですが、価格に負けて互換品を購入しました。使用方法は、UART制御でSD内のMP3を再生し、BUSY信号をチェックして再生の完了を確認するようにします。それぞれの接続は基本通りですね

早速、スケッチを記述しますが、動きません。ライブラリは”DFRobotDFPlayerMini”を最初使用していましたが動く気配がありません。調べていくと互換機は、このライブラリでは正常に動作しないという記述を見つけ、”DFPlayer Mini Mp3 by Makuna”などの別ライブラリも試しましたがやはり動作しませんでした。DFplayerのIO_1やIO_2をGNDに接続して、試したところ再生されましたのでモジュールが壊れている可能性は低そうです

そこで互換機に関する内容をネットで検索しまくったところ、初期の互換機と現在の物ではチップが異なっているという記載を見つけました。そこで、互換機のチップを確認するとTD5580Aと記載されていました

ちなみにDFRobot のDFplayer miniは下記になります

そこで互換品のTD5580Aで調べたところ、 SerialMP3と言うライブラリを見つけました。このライブラリは、互換品のチップに合わせて作られているようです。早速、このライブラリを使用してスケッチを記述したところ、簡単に動作しました(5Vを供給しないと再生しません)。なお、MP3ファイルはSDカードの直下に保存して使用しています

#include <M5unified .h>
#include <SerialMP3.h>

#define RX_PIN 22   // RX pin   22
#define TX_PIN 21   // TX pin   21
#define BUSY_PIN 36 // BUSY pin 36

SerialMP3 mp3(RX_PIN, TX_PIN);

void setup() {
  auto cfg = M5.config();
  M5.begin(cfg);

  pinMode(BUSY_PIN, INPUT);

  // put your setup code here, to run once:
  mp3.showDebug(true); // print command send to Serial MP3 Player
  Serial.begin(9600);  // Start serial interface
  mp3.init();          // MP3 Player の祖帰化  
  mp3.setVolume(20);   // ボリューム設定(0-30)
  mp3.play(2); // play exam.mp3
  while(digitalRead(BUSY_PIN) == LOW){
    delay(100);
  }
}

void loop() {
  M5.update(); 
  if (M5.BtnA.isPressed()) {
    mp3.play(1); // play exam.mp3
    while(digitalRead(BUSY_PIN) == LOW){
      delay(100);
    }
  }
  //delay(5000); // wait 2 second
}

正規品を購入していればサクッと動いたのに、ケチったばかりにいらぬ苦労してしまいましたよ

2025年4月8日火曜日

M5STACK LCD Unitのファームウェアアップデート

M5Stamp Picoを弄っていますが、やはり液晶が欲しいなって思っちゃいました。そこで、良く使用されるI2C OLEDディスプレイとM5STACK LCD Unitを購入しました。今回は、M5STACK LCD Unitのファームウェアアップデートを行います(写真はアップデート済み)

M5STACK LCD Unitを検索するとファームウェアアップデートに関する情報が出てきます。と言うか、あまり使用例が出てこないんですよねぇ

”M5STACKのUnit LCDサイト”

上記を確認すると、I2C経由でのアップデート、または裏蓋開けてESP32ダウンローダを使用してアップデートの2つの方法がありました。蓋開けるのは面倒なので、I2C経由でのアップデートしてみようかと思います。GitHubのM5Stack Unit LCD FirmWareを確認するとマニュアルには、M5StickC Plus2は明記されていませんが、スケッチ内には記載があるので大丈夫そうです

”GitHubのM5Stack Unit LCD FirmWare”

早速、M5StickC Plus2に書き込んで実行してみましたが、searchUnitLCD()の応答待ちでスタックしているように見受けられました(LCD Unitの応答がない?!)

そこで勉強がてら、I2Cスキャナーのスケッチを作成して確認したところ、GroveコネクタのI2Cバス上にアドレスは存在していることは確認できました(スケッチは後述)

    • 内部I2Cバス:0x51(RTC), 0x61(6-axis IMU)
    • Grove I2Cバス:0x3E(LCD Unit)
    • ピンヘッダ I2Cバス:なし

流石にメーカー製のスケッチを解析する気にはなりませんでしたので、I2C経由は諦めてESP32ダウンローダ(Stamp ISPを使用)を使用することにしました

接続したら、M5Burnerから書き込んで終了(書き込む際、ESP32ダウンローダを抑えた方が接触不良なく書き込めます)。無事にアップロードできました

なお、M5STACKのUnit LCDサイト内にあるサンプル記述をM5StickC Plus2に書き込んで動作確認できました。次は、M5Stamp Picoで試したいと思います

参考までにI2Cスキャンのスケッチを下記に乗せておきます:

#include <M5unified .h>
#include <M5StickCPlus2.h>
#include <M5Unified.h>
#include "wire.h"

TwoWire *i2cWire;

uint8_t sda = -1;
uint8_t scl = -1;
uint8_t I2C_SEL = 0;

void I2C_Setting() {
  if (I2C_SEL == 1) {        // GROVEコネクタ
    sda = 32;
    scl = 33;
    Wire.begin(sda, scl);
    i2cWire = &Wire;
  } else if (I2C_SEL == 2) {  // ピンヘッダー
    Wire1.end();              // Wire1を終了し再割り当て
    sda = 0;
    scl = 26;
    Wire1.begin(sda, scl);
    i2cWire = &Wire1;
  } else {                    // 内部I2C
    Wire1.end();
    sda = 21;
    scl = 22;
    Wire1.begin(sda, scl);    // Wire1:通常内部I2C
    i2cWire = &Wire1;
  }
}

void setup() {
  auto cfg = M5.config();
  M5.begin(cfg);

  M5.Lcd.fillScreen(BLACK);
  M5.Lcd.setBrightness(5);
  M5.Lcd.setRotation(3);                          // 画面向き
  M5.Lcd.setTextSize(2);                          // フォントサイズ
  M5.Lcd.setTextFont(&fonts::lgfxJapanGothic_8);  // フォント
}

void loop() {
  int device_cnt = 0;

  M5.Lcd.fillScreen(BLACK);
  M5.Lcd.setCursor(0, 0);

  M5.Lcd.printf("I2Cスキャン:\n");

  I2C_SEL = 0;
  while (I2C_SEL < 3) {
    I2C_Setting();

    if (I2C_SEL == 1) {
      M5.Lcd.printf("Groce: SDA:%2d SCL:%2d\n", sda, scl);
    } else if (I2C_SEL == 2) {
      M5.Lcd.printf("ピン : SDA:%2d SCL:%2d\n", sda, scl);
    } else {
      M5.Lcd.printf("内部 : SDA:%2d SCL:%2d\n", sda, scl);
    }

    device_cnt = 0;
    for (byte address = 0; address <= 127; address++) {
      i2cWire->beginTransmission(address);
      byte error = i2cWire->endTransmission();
      if (error == 0) {
        M5.Lcd.printf("0x%02X ", address);
        device_cnt++;
      }
      delay(1);
    }
    I2C_SEL++;
    if (device_cnt == 0) {
      M5.Lcd.printf("I2Cデバイスが見つからない!");
    }
    M5.Lcd.println();
  }
  delay(3000);
}


参考にさせて頂きましたサイト:

2025年4月5日土曜日

M5Stamp PicoでLチカ(WS2812)

Aliexpressで面白うそうなLEDモジュールを見つけたので、M5Stamp PicoでLチカ 第2弾をしました。なお、このLEDモジュールはアマゾンでも販売していました

このLEDモジュールはWS2812 5050を8個搭載しており、1本のデータ信号でこれらを制御することが出来ます。それにより1モジュール1ピンとなるため、GPIOピンの節約が出来そうです。今回もナイトライダー風にしますが、折角なのでパターン違いで2モジュール制御したいと思います。回路は非常に簡単です


本モジュールの制御には、Adafruit_NeoPixelライブラリを使用しました。ArduinoIDEのライブラリマネージャーで簡単に追加できます

// LED 制御(WS2812B)

#include <M5unified .h>
#include <dafruit_NeoPixel.h>
#define PIN1 18                 // LEDのデータを接続するGPIO
#define PIN2 19                 // LEDのデータを接続するGPIO
#define LED_NUM  8              // 接続LED数(4の倍数)
#define LED_MSK (LED_NUM/2) -1
#define LED_DLY 50              // 点灯時間
#define MAX_LED 128             // 明るさ

// LED config
Adafruit_NeoPixel strip1 = Adafruit_NeoPixel(LED_NUM, PIN1, NEO_GRB + NEO_KHZ800);
Adafruit_NeoPixel strip2 = Adafruit_NeoPixel(LED_NUM, PIN2, NEO_GRB + NEO_KHZ800);


void setup() {
  auto cfg = M5.config();
  M5.begin(cfg);
  
  // LED setup
  strip1.begin();
  strip2.begin();
}


int z = 0;
void loop() {
  int x = 0;
  int y = 0;

  for (int i = 0; i < LED_NUM; i++ ){

    // LED1 設定
    strip1.clear();  // LED1 消灯
    x = i & LED_MSK;
    y = ~x & (LED_NUM-1);
    strip1.setPixelColor(x, strip1.Color(0, MAX_LED, 0)); 
    strip1.setPixelColor(y, strip1.Color(0, MAX_LED, 0)); 
    strip1.show();

    // LED2 設定
    strip2.clear();  // LED2 消灯
    if ((z % 2) == 0) {
      strip2.setPixelColor((i), strip2.Color(0, MAX_LED, 0)); 
    } else {
      strip2.setPixelColor(((LED_NUM-1)-i), strip2.Color(0, MAX_LED, 0));
    }
    strip2.show();

    delay(LED_DLY);
  }
  z++;
}

13行目、14行目のAdafruit_NeoPixel宣言は、モジュール内のLED総数、割当てピン、蘇秦データのカラー順序(今回はRGB)、駆動周波数は800KHzで設定しています

22行目、23行目の.begin()でGPIOの出力設定が行われます

25行目、43行目の.clean()で全てのLEDを消灯しています

38,39行目、45,47行目の.setPixelColor()で表示するLEDとカラー(RGB順)を設定します(今回は緑色にしています)

なお、strip1はLED 0 → 3、LED 7 → 4の順で2個づつ表示、strip2はLED 0 → 7 → 0の順で表示しています

カラー設定値を半分にして明るさが変わるか試しましたが、これでも眩しいです


次は何をしてみようかな...